feat: 切换后端至PaddleOCR-NCNN，切换工程为CMake

1.项目后端整体迁移至PaddleOCR-NCNN算法，已通过基本的兼容性测试
2.工程改为使用CMake组织，后续为了更好地兼容第三方库，不再提供QMake工程
3.重整权利声明文件，重整代码工程，确保最小化侵权风险

Log: 切换后端至PaddleOCR-NCNN，切换工程为CMake
Change-Id: I4d5d2c5d37505a4a24b389b1a4c5d12f17bfa38c

3rdparty/opencv-4.5.4/modules/objc/generator/CMakeLists.txt

@@ -0,0 +1,125 @@
+set(MODULE_NAME "objc_bindings_generator")
+set(OPENCV_MODULE_IS_PART_OF_WORLD FALSE)
+ocv_add_module(${MODULE_NAME} INTERNAL opencv_core opencv_imgproc)
+
+#set(OPENCV_OBJC_SIGNATURES_FILE "${CMAKE_CURRENT_BINARY_DIR}/opencv_objc_signatures.json" CACHE INTERNAL "")
+set(OPENCV_OBJC_BINDINGS_DIR "${CMAKE_CURRENT_BINARY_DIR}" CACHE INTERNAL "")
+
+file(REMOVE_RECURSE "${OPENCV_OBJC_BINDINGS_DIR}/osx")
+file(REMOVE "${OPENCV_DEPHELPER}/gen_opencv_objc_source_osx")  # force re-run after CMake
+file(REMOVE_RECURSE "${OPENCV_OBJC_BINDINGS_DIR}/ios")
+file(REMOVE "${OPENCV_DEPHELPER}/gen_opencv_objc_source_ios")  # force re-run after CMake
+
+# This file is included from a subdirectory
+set(OBJC_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/..")
+include(${OBJC_SOURCE_DIR}/common.cmake)  # fill OPENCV_OBJC_MODULES
+
+# common files
+file(GLOB_RECURSE deps "${CMAKE_CURRENT_SOURCE_DIR}/templates/*")
+
+set(__modules_config "") # list of OpenCV modules
+foreach(m ${OPENCV_OBJC_MODULES})
+  set(module_objc_dir "${OPENCV_MODULE_${m}_LOCATION}/misc/objc")
+  list(APPEND deps ${OPENCV_MODULE_${m}_HEADERS})
+  file(GLOB_RECURSE misc_files "${module_objc_dir}/*")
+  list(APPEND deps ${misc_files})
+
+  string(REGEX REPLACE "^opencv_" "" m_ "${m}")
+  if(__modules_config)
+    set(__modules_config "${__modules_config},\n")
+  endif()
+  file(RELATIVE_PATH rel_path "${OpenCV_SOURCE_DIR}" "${OPENCV_MODULE_${m}_LOCATION}")
+  set(__modules_config "${__modules_config}    { \"name\": \"${m_}\", \"location\": \"${rel_path}\" }")
+endforeach(m)
+
+if(HAVE_opencv_objc)
+  set(__objc_build_dir "\"objc_build_dir\": \"${CMAKE_CURRENT_BINARY_DIR}/../objc\",")
+endif()
+
+set(CONFIG_FILE "${CMAKE_CURRENT_BINARY_DIR}/gen_objc.json")
+set(__config_str
+"{
+  \"rootdir\": \"${OpenCV_SOURCE_DIR}\",
+  ${__objc_build_dir}
+  \"modules\": [
+${__modules_config}
+  ]
+}
+")
+#TODO: ocv_update_file("${CONFIG_FILE}" "${__config_str}" ON_CHANGE_REMOVE "${OPENCV_DEPHELPER}/gen_opencv_objc_source")
+if(EXISTS "${CONFIG_FILE}")
+  file(READ "${CONFIG_FILE}" __content)
+else()
+  set(__content "")
+endif()
+if(NOT "${__content}" STREQUAL "${__config_str}")
+  file(WRITE "${CONFIG_FILE}" "${__config_str}")
+  file(REMOVE "${OPENCV_DEPHELPER}/gen_opencv_objc_source")
+endif()
+unset(__config_str)
+
+set(objc_generated_files
+    # "${OPENCV_OBJC_SIGNATURES_FILE}"
+)
+
+string(REPLACE "opencv_" "" MODULES "${OPENCV_OBJC_MODULES}")
+
+if(NOT DEFINED OPENCV_OBJC_TARGET AND APPLE_FRAMEWORK)
+  if(IOS)
+    set(OPENCV_OBJC_TARGET "ios")
+  else()
+    set(OPENCV_OBJC_TARGET "osx")
+  endif()
+endif()
+
+if(NOT DEFINED OPENCV_OBJC_FRAMEWORK_NAME)
+  if(DEFINED FRAMEWORK_NAME)
+    set(OPENCV_OBJC_FRAMEWORK_NAME "${FRAMEWORK_NAME}")
+  else()
+    set(OPENCV_OBJC_FRAMEWORK_NAME "opencv2")
+  endif()
+endif()
+
+set(objc_generated_targets "")
+
+macro(ocv_add_objc_generated_target TARGET)
+  set(objc_${TARGET}_generated_output_dependecy "${OPENCV_DEPHELPER}/gen_opencv_objc_source_${TARGET}")
+  file(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${TARGET}")
+  add_custom_command(
+      OUTPUT ${objc_generated_files} "${objc_${TARGET}_generated_output_dependecy}"
+      COMMAND ${PYTHON_DEFAULT_EXECUTABLE} "${OBJC_SOURCE_DIR}/generator/gen_objc.py"
+              -p "${OBJC_SOURCE_DIR}/../python/src2/gen2.py"
+              -c "${CONFIG_FILE}"
+              -t "${TARGET}"
+              -f "${OPENCV_OBJC_FRAMEWORK_NAME}"
+      COMMAND ${CMAKE_COMMAND} -E touch "${objc_${TARGET}_generated_output_dependecy}"
+      WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${TARGET}"
+      DEPENDS "${OpenCV_SOURCE_DIR}/modules/objc/generator/gen_objc.py"
+              "${OpenCV_SOURCE_DIR}/modules/python/src2/gen2.py"
+              "${OpenCV_SOURCE_DIR}/modules/python/src2/hdr_parser.py"
+              # don't, result of file(WRITE): "${CMAKE_CURRENT_BINARY_DIR}/gen_objc.json"
+              ${deps}
+              # not allowed (file(WRITE) result): "${CONFIG_FILE}"
+      COMMENT "Generate files for Objective-C bindings (${TARGET})"
+  )
+  add_custom_target(gen_opencv_objc_source_${TARGET}
+      # excluded from all: ALL
+      DEPENDS ${objc_generated_files} ${objc_${TARGET}_generated_output_dependecy}
+      SOURCES "${OBJC_SOURCE_DIR}/generator/gen_objc.py"
+              "${OBJC_SOURCE_DIR}/generator/templates/cmakelists.template"
+              "${CMAKE_CURRENT_BINARY_DIR}/gen_objc.json"
+  )
+  list(APPEND objc_generated_targets gen_opencv_objc_source_${TARGET})
+endmacro()
+
+if(OPENCV_OBJC_TARGET)
+  ocv_add_objc_generated_target(${OPENCV_OBJC_TARGET})
+else()
+  ocv_add_objc_generated_target(osx)
+  ocv_add_objc_generated_target(ios)
+endif()
+
+add_custom_target(gen_opencv_objc_source
+    # excluded from all: ALL
+    DEPENDS ${objc_generated_targets}
+)

3rdparty/opencv-4.5.4/modules/objc/generator/templates/cmakelists.template

@@ -0,0 +1,68 @@
+cmake_minimum_required(VERSION 3.15)
+
+project($framework)
+
+set(MODULES "$modules")
+
+# Enable C++11
+set (CMAKE_CXX_STANDARD 11)
+set (CMAKE_CXX_STANDARD_REQUIRED TRUE)
+
+set (OBJC_COMPILE_FLAGS "-fobjc-arc -fobjc-weak -fvisibility=hidden -fPIC -D__OPENCV_BUILD=1")
+set (SUPPRESS_WARNINGS_FLAGS "-Wno-incomplete-umbrella")
+set (CMAKE_CXX_FLAGS  "$${CMAKE_CXX_FLAGS} $${OBJC_COMPILE_FLAGS} $${SUPPRESS_WARNINGS_FLAGS}")
+
+# grab the files
+if(SWIFT_DISABLED)
+  message(STATUS "Swift wrapper disabled")
+  file(GLOB_RECURSE objc_sources "objc/*\.h" "objc/*\.m" "objc/*\.mm" "objc/*\.modulemap")
+else()
+  enable_language(Swift)
+  file(GLOB_RECURSE objc_sources "objc/*\.h" "objc/*\.m" "objc/*\.mm" "objc/*\.swift" "objc/*\.modulemap")
+endif()
+file(GLOB_RECURSE objc_headers "*\.h")
+
+add_library($framework STATIC $${objc_sources})
+
+set_target_properties($framework PROPERTIES LINKER_LANGUAGE CXX)
+
+target_include_directories($framework PRIVATE "$${BUILD_ROOT}")
+target_include_directories($framework PRIVATE "$${BUILD_ROOT}/install/include")
+target_include_directories($framework PRIVATE "$${BUILD_ROOT}/install/include/opencv2")
+foreach(m $${MODULES})
+  target_include_directories($framework PRIVATE "$${BUILD_ROOT}/modules/objc_bindings_generator/$objc_target/gen/objc/$${m}")
+endforeach()
+
+install(TARGETS $framework LIBRARY DESTINATION lib)
+
+# Additional target properties
+if (CMAKE_XCODE_BUILD_SYSTEM GREATER_EQUAL 12)
+  set_target_properties($framework PROPERTIES
+      OUTPUT_NAME "$framework"
+      ARCHIVE_OUTPUT_DIRECTORY "$${BUILD_ROOT}/lib"
+      XCODE_ATTRIBUTE_SWIFT_VERSION 5.0
+      XCODE_ATTRIBUTE_DEFINES_MODULE YES
+      XCODE_ATTRIBUTE_BUILD_LIBRARY_FOR_DISTRIBUTION YES
+      XCODE_ATTRIBUTE_OTHER_SWIFT_FLAGS "-Xcc $${SUPPRESS_WARNINGS_FLAGS}"
+      XCODE_ATTRIBUTE_MODULEMAP_FILE objc/$framework.modulemap
+      XCODE_ATTRIBUTE_PRODUCT_BUNDLE_IDENTIFIER org.opencv.$framework
+      FRAMEWORK TRUE
+      MACOSX_FRAMEWORK_IDENTIFIER org.opencv.$framework
+      PUBLIC_HEADER "$${objc_headers}"
+      DEFINE_SYMBOL CVAPI_EXPORTS
+      )
+else()
+  set_target_properties($framework PROPERTIES
+      OUTPUT_NAME "$framework"
+      ARCHIVE_OUTPUT_DIRECTORY "$${BUILD_ROOT}/lib"
+      XCODE_ATTRIBUTE_SWIFT_VERSION 5.0
+      XCODE_ATTRIBUTE_DEFINES_MODULE YES
+      XCODE_ATTRIBUTE_OTHER_SWIFT_FLAGS "-Xcc $${SUPPRESS_WARNINGS_FLAGS}"
+      XCODE_ATTRIBUTE_MODULEMAP_FILE objc/$framework.modulemap
+      XCODE_ATTRIBUTE_PRODUCT_BUNDLE_IDENTIFIER org.opencv.$framework
+      FRAMEWORK TRUE
+      MACOSX_FRAMEWORK_IDENTIFIER org.opencv.$framework
+      PUBLIC_HEADER "$${objc_headers}"
+      DEFINE_SYMBOL CVAPI_EXPORTS
+      )
+endif()

3rdparty/opencv-4.5.4/modules/objc/generator/templates/objc_class_body.template

@@ -0,0 +1,16 @@
+//
+// This file is auto-generated. Please don't modify it!
+//
+
+#import "$objcName.h"
+#import "CVObjcUtil.h"
+
+$imports
+
+@implementation $objcName
+
+$nativePointerHandling
+
+$methodImplementations
+
+@end

3rdparty/opencv-4.5.4/modules/objc/generator/templates/objc_class_header.template

@@ -0,0 +1,31 @@
+//
+// This file is auto-generated. Please don't modify it!
+//
+#pragma once
+
+#ifdef __cplusplus
+//#import "opencv.hpp"
+$additionalImports
+#else
+#define CV_EXPORTS
+#endif
+
+#import <Foundation/Foundation.h>
+$importBaseClass
+
+$forwardDeclarations
+
+$enumDeclarations
+
+NS_ASSUME_NONNULL_BEGIN
+
+$docs
+CV_EXPORTS @interface $objcName : $base
+
+$nativePointerHandling
+
+$methodDeclarations
+
+@end
+
+NS_ASSUME_NONNULL_END

3rdparty/opencv-4.5.4/modules/objc/generator/templates/objc_module_body.template

@@ -0,0 +1,14 @@
+//
+// This file is auto-generated. Please don't modify it!
+//
+
+#import "$module.h"
+#import "CVObjcUtil.h"
+
+$imports
+
+@implementation $module
+
+$methodImplementations
+
+@end

3rdparty/opencv-4.5.4/modules/objc/generator/templates/objc_module_header.template

@@ -0,0 +1,28 @@
+//
+// This file is auto-generated. Please don't modify it!
+//
+#pragma once
+
+#ifdef __cplusplus
+//#import "opencv.hpp"
+$additionalImports
+#else
+#define CV_EXPORTS
+#endif
+
+#import <Foundation/Foundation.h>
+
+$forwardDeclarations
+
+$enumDeclarations
+
+NS_ASSUME_NONNULL_BEGIN
+
+$docs
+CV_EXPORTS @interface $module : $base
+
+$methodDeclarations
+
+@end
+
+NS_ASSUME_NONNULL_END