feat: 切换后端至PaddleOCR-NCNN，切换工程为CMake

1.项目后端整体迁移至PaddleOCR-NCNN算法，已通过基本的兼容性测试 2.工程改为使用CMake组织，后续为了更好地兼容第三方库，不再提供QMake工程 3.重整权利声明文件，重整代码工程，确保最小化侵权风险 Log: 切换后端至PaddleOCR-NCNN，切换工程为CMake Change-Id: I4d5d2c5d37505a4a24b389b1a4c5d12f17bfa38c
2022-05-10 09:54:44 +08:00
parent ecdd171c6f
commit 718c41634f
10018 changed files with 3593797 additions and 186748 deletions
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_android_camera.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_android_camera.cmake
@ -0,0 +1,6 @@
+# if(ANDROID AND ANDROID_NATIVE_API_LEVEL GREATER_EQUAL 24)  <-- would be nicer but requires CMake 3.7 or later
+if(ANDROID AND ANDROID_NATIVE_API_LEVEL GREATER 23)
+  set(HAVE_ANDROID_NATIVE_CAMERA TRUE)
+  set(libs "-landroid -llog -lcamera2ndk")
+  ocv_add_external_target(android_native_camera "" "${libs}" "HAVE_ANDROID_NATIVE_CAMERA")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_android_mediandk.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_android_mediandk.cmake
@ -0,0 +1,6 @@
+# if(ANDROID AND ANDROID_NATIVE_API_LEVEL GREATER_EQUAL 21)  <-- would be nicer but requires CMake 3.7 or later
+if(ANDROID AND ANDROID_NATIVE_API_LEVEL GREATER 20)
+  set(HAVE_ANDROID_MEDIANDK TRUE)
+  set(libs "-landroid -llog -lmediandk")
+  ocv_add_external_target(android_mediandk "" "${libs}" "HAVE_ANDROID_MEDIANDK")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_aravis.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_aravis.cmake
@ -0,0 +1,32 @@
+# --- Aravis SDK ---
+if(NOT HAVE_ARAVIS_API AND PKG_CONFIG_FOUND)
+  ocv_check_modules(ARAVIS aravis-0.6 QUIET)
+  if(ARAVIS_FOUND)
+    set(HAVE_ARAVIS_API TRUE)
+  endif()
+endif()
+
+if(NOT HAVE_ARAVIS_API)
+  find_path(ARAVIS_INCLUDE "arv.h"
+    PATHS "${ARAVIS_ROOT}" ENV ARAVIS_ROOT
+    PATH_SUFFIXES "include/aravis-0.6"
+    NO_DEFAULT_PATH)
+  find_library(ARAVIS_LIBRARY "aravis-0.6"
+    PATHS "${ARAVIS_ROOT}" ENV ARAVIS_ROOT
+    PATH_SUFFIXES "lib"
+    NO_DEFAULT_PATH)
+  if(ARAVIS_INCLUDE AND ARAVIS_LIBRARY)
+    set(HAVE_ARAVIS_API TRUE)
+    file(STRINGS "${ARAVIS_INCLUDE}/arvversion.h" ver_strings REGEX "#define +ARAVIS_(MAJOR|MINOR|MICRO)_VERSION.*")
+    string(REGEX REPLACE ".*ARAVIS_MAJOR_VERSION[^0-9]+([0-9]+).*" "\\1" ver_major "${ver_strings}")
+    string(REGEX REPLACE ".*ARAVIS_MINOR_VERSION[^0-9]+([0-9]+).*" "\\1" ver_minor "${ver_strings}")
+    string(REGEX REPLACE ".*ARAVIS_MICRO_VERSION[^0-9]+([0-9]+).*" "\\1" ver_micro "${ver_strings}")
+    set(ARAVIS_VERSION "${ver_major}.${ver_minor}.${ver_micro}")  # informational
+    set(ARAVIS_INCLUDE_DIRS "${ARAVIS_INCLUDE}")
+    set(ARAVIS_LIBRARIES "${ARAVIS_LIBRARY}")
+  endif()
+endif()
+
+if(HAVE_ARAVIS_API)
+  ocv_add_external_target(aravis "${ARAVIS_INCLUDE_DIRS}" "${ARAVIS_LIBRARIES}" "HAVE_ARAVIS_API")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_avfoundation.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_avfoundation.cmake
@ -0,0 +1,16 @@
+if(APPLE)
+  set(HAVE_AVFOUNDATION TRUE)
+  if(IOS)
+    set(libs "-framework AVFoundation" "-framework QuartzCore")
+  else()
+    set(libs
+      "-framework Cocoa"
+      "-framework Accelerate"
+      "-framework AVFoundation"
+      "-framework CoreGraphics"
+      "-framework CoreMedia"
+      "-framework CoreVideo"
+      "-framework QuartzCore")
+  endif()
+  ocv_add_external_target(avfoundation "" "${libs}" "HAVE_AVFOUNDATION")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_dc1394.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_dc1394.cmake
@ -0,0 +1,28 @@
+# --- Dc1394 ---
+if(NOT HAVE_DC1394_2 AND PKG_CONFIG_FOUND)
+  ocv_check_modules(DC1394_2 libdc1394-2)
+  if(DC1394_2_FOUND)
+    set(HAVE_DC1394_2 TRUE)
+  endif()
+endif()
+
+if(NOT HAVE_DC1394_2)
+  find_path(DC1394_INCLUDE "dc1394/dc1394.h"
+    PATHS "${DC1394_ROOT}" ENV DC1394_ROOT
+    PATH_SUFFIXES "include"
+    NO_DEFAULT_PATH)
+  find_library(DC1394_LIBRARY "dc1394"
+    PATHS "${DC1394_ROOT}" ENV DC1394_ROOT
+    PATH_SUFFIXES "lib"
+    NO_DEFAULT_PATH)
+  if(DC1394_INCLUDE AND DC1394_LIBRARY)
+    set(HAVE_DC1394_2 TRUE)
+    set(DC1394_2_INCLUDE_DIRS "${DC1394_INCLUDE}")
+    set(DC1394_2_LIBRARIES "${DC1394_LIBRARY}")
+    set(DC1394_2_VERSION "unknown") # informational
+  endif()
+endif()
+
+if(HAVE_DC1394_2)
+  ocv_add_external_target(dc1394_2 "${DC1394_2_INCLUDE_DIRS}" "${DC1394_2_LIBRARIES}" "HAVE_DC1394_2")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_dshow.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_dshow.cmake
@ -0,0 +1,12 @@
+# --- VideoInput/DirectShow ---
+if(NOT HAVE_DSHOW AND MSVC AND NOT MSVC_VERSION LESS 1500)
+  set(HAVE_DSHOW TRUE)
+endif()
+
+if(NOT HAVE_DSHOW)
+  check_include_file(dshow.h HAVE_DSHOW)
+endif()
+
+if(HAVE_DSHOW)
+  ocv_add_external_target(dshow "" "" "HAVE_DSHOW")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_ffmpeg.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_ffmpeg.cmake
@ -0,0 +1,129 @@
+# --- FFMPEG ---
+if(NOT HAVE_FFMPEG AND OPENCV_FFMPEG_USE_FIND_PACKAGE)
+  if(OPENCV_FFMPEG_USE_FIND_PACKAGE STREQUAL "1" OR OPENCV_FFMPEG_USE_FIND_PACKAGE STREQUAL "ON")
+    set(OPENCV_FFMPEG_USE_FIND_PACKAGE "FFMPEG")
+  endif()
+  find_package(${OPENCV_FFMPEG_USE_FIND_PACKAGE}) # Required components: AVCODEC AVFORMAT AVUTIL SWSCALE
+  if(FFMPEG_FOUND OR FFmpeg_FOUND)
+    set(HAVE_FFMPEG TRUE)
+  endif()
+endif()
+
+if(NOT HAVE_FFMPEG AND WIN32 AND NOT ARM AND NOT OPENCV_FFMPEG_SKIP_DOWNLOAD)
+  include("${OpenCV_SOURCE_DIR}/3rdparty/ffmpeg/ffmpeg.cmake")
+  download_win_ffmpeg(FFMPEG_CMAKE_SCRIPT)
+  if(FFMPEG_CMAKE_SCRIPT)
+    include("${FFMPEG_CMAKE_SCRIPT}")
+    set(HAVE_FFMPEG TRUE)
+    set(HAVE_FFMPEG_WRAPPER TRUE)
+  endif()
+endif()
+
+set(_required_ffmpeg_libraries libavcodec libavformat libavutil libswscale)
+set(_used_ffmpeg_libraries ${_required_ffmpeg_libraries})
+if(NOT HAVE_FFMPEG AND PKG_CONFIG_FOUND)
+  ocv_check_modules(FFMPEG libavcodec libavformat libavutil libswscale)
+  if(FFMPEG_FOUND)
+    ocv_check_modules(FFMPEG_libavresample libavresample) # optional
+    if(FFMPEG_libavresample_FOUND)
+      list(APPEND FFMPEG_LIBRARIES ${FFMPEG_libavresample_LIBRARIES})
+      list(APPEND _used_ffmpeg_libraries libavresample)
+    endif()
+    set(HAVE_FFMPEG TRUE)
+  else()
+    set(_missing_ffmpeg_libraries "")
+    foreach (ffmpeg_lib ${_required_ffmpeg_libraries})
+      if (NOT FFMPEG_${ffmpeg_lib}_FOUND)
+        list(APPEND _missing_ffmpeg_libraries ${ffmpeg_lib})
+      endif()
+    endforeach ()
+    message(STATUS "FFMPEG is disabled. Required libraries: ${_required_ffmpeg_libraries}."
+            " Missing libraries: ${_missing_ffmpeg_libraries}")
+    unset(_missing_ffmpeg_libraries)
+  endif()
+endif()
+
+#=================================
+# Versions check.
+if(HAVE_FFMPEG AND NOT HAVE_FFMPEG_WRAPPER)
+  set(_min_libavcodec_version 54.35.0)
+  set(_min_libavformat_version 54.20.4)
+  set(_min_libavutil_version 52.3.0)
+  set(_min_libswscale_version 2.1.1)
+  set(_min_libavresample_version 1.0.1)
+  foreach(ffmpeg_lib ${_used_ffmpeg_libraries})
+    if(FFMPEG_${ffmpeg_lib}_VERSION VERSION_LESS _min_${ffmpeg_lib}_version)
+      message(STATUS "FFMPEG is disabled. Can't find suitable ${ffmpeg_lib} library"
+              " (minimal ${_min_${ffmpeg_lib}_version}, found ${FFMPEG_${ffmpeg_lib}_VERSION}).")
+      set(HAVE_FFMPEG FALSE)
+    endif()
+  endforeach()
+  if(NOT HAVE_FFMPEG)
+    message(STATUS "FFMPEG libraries version check failed "
+            "(minimal libav release 9.20, minimal FFMPEG release 1.1.16).")
+  endif()
+  unset(_min_libavcodec_version)
+  unset(_min_libavformat_version)
+  unset(_min_libavutil_version)
+  unset(_min_libswscale_version)
+  unset(_min_libavresample_version)
+endif()
+
+#==================================
+
+if(HAVE_FFMPEG AND NOT HAVE_FFMPEG_WRAPPER AND NOT OPENCV_FFMPEG_SKIP_BUILD_CHECK)
+  try_compile(__VALID_FFMPEG
+      "${OpenCV_BINARY_DIR}"
+      "${OpenCV_SOURCE_DIR}/cmake/checks/ffmpeg_test.cpp"
+      CMAKE_FLAGS "-DINCLUDE_DIRECTORIES:STRING=${FFMPEG_INCLUDE_DIRS}"
+                  "-DLINK_LIBRARIES:STRING=${FFMPEG_LIBRARIES}"
+      OUTPUT_VARIABLE TRY_OUT
+  )
+  if(NOT __VALID_FFMPEG)
+    # message(FATAL_ERROR "FFMPEG: test check build log:\n${TRY_OUT}")
+    message(STATUS "WARNING: Can't build ffmpeg test code")
+    set(HAVE_FFMPEG FALSE)
+  endif()
+endif()
+
+#==================================
+unset(_required_ffmpeg_libraries)
+unset(_used_ffmpeg_libraries)
+
+if(HAVE_FFMPEG_WRAPPER)
+  ocv_add_external_target(ffmpeg "" "" "HAVE_FFMPEG_WRAPPER")
+elseif(HAVE_FFMPEG)
+  ocv_add_external_target(ffmpeg "${FFMPEG_INCLUDE_DIRS}" "${FFMPEG_LIBRARIES}" "HAVE_FFMPEG")
+  set(__builtin_defines "")
+  set(__builtin_include_dirs "")
+  set(__builtin_libs "")
+  set(__plugin_defines "")
+  set(__plugin_include_dirs "")
+  set(__plugin_libs "")
+  if(HAVE_OPENCL)
+    set(__opencl_dirs "")
+    if(OPENCL_INCLUDE_DIRS)
+      set(__opencl_dirs "${OPENCL_INCLUDE_DIRS}")
+    elseif(OPENCL_INCLUDE_DIR)
+      set(__opencl_dirs "${OPENCL_INCLUDE_DIR}")
+    else()
+      set(__opencl_dirs "${OpenCV_SOURCE_DIR}/3rdparty/include/opencl/1.2")
+    endif()
+    # extra dependencies for buildin code (OpenCL dir is required for extensions like cl_d3d11.h)
+    # buildin HAVE_OPENCL is already defined through cvconfig.h
+    list(APPEND __builtin_include_dirs "${__opencl_dirs}")
+
+    # extra dependencies for
+    list(APPEND __plugin_defines "HAVE_OPENCL")
+    list(APPEND __plugin_include_dirs "${__opencl_dirs}")
+  endif()
+
+  # TODO: libva, d3d11
+
+  if(__builtin_include_dirs OR __builtin_include_defines OR __builtin_include_libs)
+    ocv_add_external_target(ffmpeg.builtin_deps "${__builtin_include_dirs}" "${__builtin_include_libs}" "${__builtin_defines}")
+  endif()
+  if(VIDEOIO_ENABLE_PLUGINS AND __plugin_include_dirs OR __plugin_include_defines OR __plugin_include_libs)
+    ocv_add_external_target(ffmpeg.plugin_deps "${__plugin_include_dirs}" "${__plugin_include_libs}" "${__plugin_defines}")
+  endif()
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_gphoto.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_gphoto.cmake
@ -0,0 +1,11 @@
+# --- gPhoto2 ---
+if(NOT HAVE_GPHOTO2 AND PKG_CONFIG_FOUND)
+  ocv_check_modules(GPHOTO2 libgphoto2)
+  if(GPHOTO2_FOUND)
+    set(HAVE_GPHOTO2 TRUE)
+  endif()
+endif()
+
+if(HAVE_GPHOTO2)
+  ocv_add_external_target(gphoto2 "${GPHOTO2_INCLUDE_DIRS}" "${GPHOTO2_LIBRARIES}" "HAVE_GPHOTO2")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_gstreamer.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_gstreamer.cmake
@ -0,0 +1,106 @@
+# --- GStreamer ---
+if(NOT HAVE_GSTREAMER AND WIN32)
+  set(env_paths "${GSTREAMER_DIR}" ENV GSTREAMER_ROOT)
+  if(X86_64)
+    list(APPEND env_paths ENV GSTREAMER_1_0_ROOT_X86_64 ENV GSTREAMER_ROOT_X86_64)
+  else()
+    list(APPEND env_paths ENV GSTREAMER_1_0_ROOT_X86 ENV GSTREAMER_ROOT_X86)
+  endif()
+
+  find_path(GSTREAMER_gst_INCLUDE_DIR
+    gst/gst.h
+    PATHS ${env_paths}
+    PATH_SUFFIXES "include/gstreamer-1.0")
+  find_path(GSTREAMER_glib_INCLUDE_DIR
+    glib.h
+    PATHS ${env_paths}
+    PATH_SUFFIXES "include/glib-2.0")
+  find_path(GSTREAMER_glibconfig_INCLUDE_DIR
+    glibconfig.h
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib/glib-2.0/include")
+
+  find_library(GSTREAMER_gstreamer_LIBRARY
+    NAMES gstreamer gstreamer-1.0
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib")
+  find_library(GSTREAMER_app_LIBRARY
+    NAMES gstapp gstapp-1.0
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib")
+  find_library(GSTREAMER_base_LIBRARY
+    NAMES gstbase gstbase-1.0
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib")
+  find_library(GSTREAMER_pbutils_LIBRARY
+    NAMES gstpbutils gstpbutils-1.0
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib")
+  find_library(GSTREAMER_riff_LIBRARY
+    NAMES gstriff gstriff-1.0
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib")
+  find_library(GSTREAMER_video_LIBRARY
+    NAMES gstvideo gstvideo-1.0
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib")
+
+  find_library(GSTREAMER_glib_LIBRARY
+    NAMES glib-2.0
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib")
+  find_library(GSTREAMER_gobject_LIBRARY
+    NAMES gobject-2.0
+    PATHS ${env_paths}
+    PATH_SUFFIXES "lib")
+
+  if(GSTREAMER_gst_INCLUDE_DIR
+      AND GSTREAMER_glib_INCLUDE_DIR
+      AND GSTREAMER_glibconfig_INCLUDE_DIR
+      AND GSTREAMER_gstreamer_LIBRARY
+      AND GSTREAMER_app_LIBRARY
+      AND GSTREAMER_base_LIBRARY
+      AND GSTREAMER_pbutils_LIBRARY
+      AND GSTREAMER_riff_LIBRARY
+      AND GSTREAMER_video_LIBRARY
+      AND GSTREAMER_glib_LIBRARY
+      AND GSTREAMER_gobject_LIBRARY)
+    file(STRINGS "${GSTREAMER_gst_INCLUDE_DIR}/gst/gstversion.h" ver_strings REGEX "#define +GST_VERSION_(MAJOR|MINOR|MICRO|NANO).*")
+    string(REGEX REPLACE ".*GST_VERSION_MAJOR[^0-9]+([0-9]+).*" "\\1" ver_major "${ver_strings}")
+    string(REGEX REPLACE ".*GST_VERSION_MINOR[^0-9]+([0-9]+).*" "\\1" ver_minor "${ver_strings}")
+    string(REGEX REPLACE ".*GST_VERSION_MICRO[^0-9]+([0-9]+).*" "\\1" ver_micro "${ver_strings}")
+    set(GSTREAMER_VERSION "${ver_major}.${ver_minor}.${ver_micro}")  # informational
+    set(HAVE_GSTREAMER TRUE)
+    set(GSTREAMER_LIBRARIES
+      ${GSTREAMER_gstreamer_LIBRARY}
+      ${GSTREAMER_base_LIBRARY}
+      ${GSTREAMER_app_LIBRARY}
+      ${GSTREAMER_riff_LIBRARY}
+      ${GSTREAMER_video_LIBRARY}
+      ${GSTREAMER_pbutils_LIBRARY}
+      ${GSTREAMER_glib_LIBRARY}
+      ${GSTREAMER_gobject_LIBRARY})
+    set(GSTREAMER_INCLUDE_DIRS
+      ${GSTREAMER_gst_INCLUDE_DIR}
+      ${GSTREAMER_glib_INCLUDE_DIR}
+      ${GSTREAMER_glibconfig_INCLUDE_DIR})
+  endif()
+endif()
+
+if(NOT HAVE_GSTREAMER AND PKG_CONFIG_FOUND)
+  ocv_check_modules(GSTREAMER_base gstreamer-base-1.0)
+  ocv_check_modules(GSTREAMER_app gstreamer-app-1.0)
+  ocv_check_modules(GSTREAMER_riff gstreamer-riff-1.0)
+  ocv_check_modules(GSTREAMER_pbutils gstreamer-pbutils-1.0)
+  ocv_check_modules(GSTREAMER_video gstreamer-video-1.0)
+  if(GSTREAMER_base_FOUND AND GSTREAMER_app_FOUND AND GSTREAMER_riff_FOUND AND GSTREAMER_pbutils_FOUND AND GSTREAMER_video_FOUND)
+    set(HAVE_GSTREAMER TRUE)
+    set(GSTREAMER_VERSION ${GSTREAMER_base_VERSION})  # informational
+    set(GSTREAMER_LIBRARIES ${GSTREAMER_base_LIBRARIES} ${GSTREAMER_app_LIBRARIES} ${GSTREAMER_riff_LIBRARIES} ${GSTREAMER_pbutils_LIBRARIES} ${GSTREAMER_video_LIBRARIES})
+    set(GSTREAMER_INCLUDE_DIRS ${GSTREAMER_base_INCLUDE_DIRS} ${GSTREAMER_app_INCLUDE_DIRS} ${GSTREAMER_riff_INCLUDE_DIRS} ${GSTREAMER_pbutils_INCLUDE_DIRS} ${GSTREAMER_video_INCLUDE_DIRS})
+  endif()
+endif()
+
+if(HAVE_GSTREAMER)
+  ocv_add_external_target(gstreamer "${GSTREAMER_INCLUDE_DIRS}" "${GSTREAMER_LIBRARIES}" "HAVE_GSTREAMER")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_ios.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_ios.cmake
@ -0,0 +1,13 @@
+if(APPLE AND IOS)
+  set(HAVE_CAP_IOS TRUE)
+  set(libs
+    "-framework Accelerate"
+    "-framework AVFoundation"
+    "-framework CoreGraphics"
+    "-framework CoreImage"
+    "-framework CoreMedia"
+    "-framework CoreVideo"
+    "-framework QuartzCore"
+    "-framework UIKit")
+  ocv_add_external_target(cap_ios "" "${libs}" "HAVE_CAP_IOS")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_msdk.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_msdk.cmake
@ -0,0 +1,72 @@
+set(MFX_DEFS "")
+
+if(NOT HAVE_MFX)
+  find_package(VPL QUIET)
+  if(VPL_FOUND)
+    set(MFX_INCLUDE_DIRS "")
+    set(MFX_LIBRARIES "${VPL_IMPORTED_TARGETS}")
+    set(HAVE_MFX TRUE)
+    list(APPEND MFX_DEFS "HAVE_ONEVPL")
+  endif()
+endif()
+
+
+if(NOT HAVE_MFX)
+  set(paths "${MFX_HOME}" ENV "MFX_HOME" ENV "INTELMEDIASDKROOT")
+  if(MSVC)
+    if(MSVC_VERSION LESS 1900)
+      set(vs_suffix)
+    else()
+      set(vs_suffix "_vs2015")
+    endif()
+    if(X86_64)
+      set(vs_arch "x64")
+    else()
+      set(vs_arch "win32")
+    endif()
+  endif()
+  find_path(MFX_INCLUDE mfxdefs.h
+    PATHS ${paths}
+    PATH_SUFFIXES "include" "include/mfx"
+    NO_DEFAULT_PATH)
+  find_library(MFX_LIBRARY NAMES mfx libmfx${vs_suffix}
+    PATHS ${paths}
+    PATH_SUFFIXES "lib64" "lib/lin_x64" "lib/${vs_arch}"
+    NO_DEFAULT_PATH)
+  if(MFX_INCLUDE AND MFX_LIBRARY)
+    set(HAVE_MFX TRUE)
+    set(MFX_INCLUDE_DIRS "${MFX_INCLUDE}")
+    set(MFX_LIBRARIES "${MFX_LIBRARY}")
+    list(APPEND MFX_DEFS "HAVE_MFX_PLUGIN")
+  endif()
+endif()
+
+if(NOT HAVE_MFX AND PKG_CONFIG_FOUND)
+  ocv_check_modules(MFX mfx)
+endif()
+
+if(HAVE_MFX AND UNIX)
+  foreach(mode NO_DEFAULT_PATH "")
+    find_path(MFX_va_INCLUDE va/va.h PATHS ${paths} PATH_SUFFIXES "include" ${mode})
+    find_library(MFX_va_LIBRARY va PATHS ${paths} PATH_SUFFIXES "lib64" "lib/lin_x64" ${mode})
+    find_library(MFX_va_drm_LIBRARY va-drm PATHS ${paths} PATH_SUFFIXES "lib64" "lib/lin_x64" ${mode})
+    if(MFX_va_INCLUDE AND MFX_va_LIBRARY AND MFX_va_drm_LIBRARY)
+      list(APPEND MFX_INCLUDE_DIRS "${MFX_va_INCLUDE}")
+      list(APPEND MFX_LIBRARIES "${MFX_va_LIBRARY}" "${MFX_va_drm_LIBRARY}")
+      # list(APPEND MFX_LIBRARIES "-Wl,--exclude-libs=libmfx")
+      break()
+    endif()
+    unset(MFX_va_INCLUDE CACHE)
+    unset(MFX_va_LIBRARY CACHE)
+    unset(MFX_va_drm_LIBRARY CACHE)
+  endforeach()
+  if(NOT(MFX_va_INCLUDE AND MFX_va_LIBRARY AND MFX_va_drm_LIBRARY))
+    set(HAVE_MFX FALSE)
+  endif()
+
+endif()
+
+if(HAVE_MFX)
+  list(APPEND MFX_DEFS "HAVE_MFX")
+  ocv_add_external_target(mediasdk "${MFX_INCLUDE_DIRS}" "${MFX_LIBRARIES}" "${MFX_DEFS}")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_msmf.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_msmf.cmake
@ -0,0 +1,22 @@
+# --- VideoInput/Microsoft Media Foundation ---
+if(NOT HAVE_MSMF)
+  check_include_file(mfapi.h HAVE_MFAPI)
+  if(HAVE_MFAPI)
+    set(HAVE_MSMF TRUE)
+  endif()
+endif()
+
+if(HAVE_MSMF)
+  if(WITH_MSMF_DXVA)
+    check_include_file(d3d11.h HAVE_D3D11)
+    check_include_file(d3d11_4.h HAVE_D3D11_4)
+    if(HAVE_D3D11 AND HAVE_D3D11_4)
+      set(HAVE_MSMF_DXVA TRUE)
+    endif()
+  endif()
+  set(defs "HAVE_MSMF")
+  if(HAVE_MSMF_DXVA)
+    list(APPEND defs "HAVE_MSMF_DXVA")
+  endif()
+  ocv_add_external_target(msmf "" "" "${defs}")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_openni2.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_openni2.cmake
@ -0,0 +1,47 @@
+# --- OpenNI2 ---
+
+if(NOT HAVE_OPENNI2)
+  set(paths "${OPENNI2_DIR}")
+  if(MSVC AND X86_64)
+    list(APPEND paths ENV OPENNI2_INCLUDE64 ENV OPENNI2_LIB64 ENV OPENNI2_REDIST64)
+  else()
+    list(APPEND paths ENV OPENNI2_INCLUDE ENV OPENNI2_LIB ENV OPENNI2_REDIST)
+  endif()
+
+  # From SDK
+  find_path(OPENNI2_INCLUDE "OpenNI.h"
+    PATHS ${paths}
+    PATH_SUFFIXES "Include"
+    NO_DEFAULT_PATH)
+  find_library(OPENNI2_LIBRARY "OpenNI2"
+    PATHS ${paths}
+    PATH_SUFFIXES "Redist" "Lib"
+    NO_DEFAULT_PATH)
+
+  if(OPENNI2_LIBRARY AND OPENNI2_INCLUDE)
+    set(HAVE_OPENNI2 TRUE)
+    set(OPENNI2_INCLUDE_DIRS "${OPENNI2_INCLUDE}")
+    set(OPENNI2_LIBRARIES "${OPENNI2_LIBRARY}")
+  endif()
+endif()
+
+if(NOT HAVE_OPENNI2)
+  # From system
+  find_path(OPENNI2_SYS_INCLUDE "OpenNI.h" PATH_SUFFIXES "openni2" "ni2")
+  find_library(OPENNI2_SYS_LIBRARY "OpenNI2")
+
+  if(OPENNI2_SYS_LIBRARY AND OPENNI2_SYS_INCLUDE)
+    set(HAVE_OPENNI2 TRUE)
+    set(OPENNI2_INCLUDE_DIRS "${OPENNI2_SYS_INCLUDE}")
+    set(OPENNI2_LIBRARIES "${OPENNI2_SYS_LIBRARY}")
+  endif()
+endif()
+
+if(HAVE_OPENNI2)
+  file(STRINGS "${OPENNI2_INCLUDE_DIRS}/OniVersion.h" ver_strings REGEX "#define +ONI_VERSION_(MAJOR|MINOR|MAINTENANCE|BUILD).*")
+  string(REGEX REPLACE ".*ONI_VERSION_MAJOR[^0-9]+([0-9]+).*" "\\1" ver_major "${ver_strings}")
+  string(REGEX REPLACE ".*ONI_VERSION_MINOR[^0-9]+([0-9]+).*" "\\1" ver_minor "${ver_strings}")
+  string(REGEX REPLACE ".*ONI_VERSION_MAINTENANCE[^0-9]+([0-9]+).*" "\\1" ver_maint "${ver_strings}")
+  set(OPENNI2_VERSION "${ver_major}.${ver_minor}.${ver_maint}")  # informational
+  ocv_add_external_target(openni2 "${OPENNI2_INCLUDE_DIRS}" "${OPENNI2_LIBRARIES}" "HAVE_OPENNI2")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_pvapi.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_pvapi.cmake
@ -0,0 +1,21 @@
+# --- PvApi ---
+if(NOT HAVE_PVAPI)
+  if(X86_64)
+    set(arch x64)
+  else()
+    set(arch x86)
+  endif()
+  find_path(PVAPI_INCLUDE "PvApi.h"
+    PATHS "${PVAPI_ROOT}" ENV PVAPI_ROOT
+    PATH_SUFFIXES "inc-pc")
+  find_library(PVAPI_LIBRARY "PvAPI"
+    PATHS "${PVAPI_ROOT}" ENV PVAPI_ROOT
+    PATH_SUFFIXES "bin-pc/${arch}/${gcc}")
+  if(PVAPI_INCLUDE AND PVAPI_LIBRARY)
+    set(HAVE_PVAPI TRUE)
+  endif()
+endif()
+
+if(HAVE_PVAPI)
+  ocv_add_external_target(pvapi "${PVAPI_INCLUDE}" "${PVAPI_LIBRARY}" "HAVE_PVAPI")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_realsense.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_realsense.cmake
@ -0,0 +1,28 @@
+# --- Intel librealsense ---
+
+if(NOT HAVE_LIBREALSENSE)
+  find_package(realsense2 QUIET)
+  if(realsense2_FOUND)
+    set(HAVE_LIBREALSENSE TRUE)
+    set(LIBREALSENSE_VERSION "${realsense2_VERSION}")  # informational
+    ocv_add_external_target(librealsense "" "${realsense2_LIBRARY}" "HAVE_LIBREALSENSE")
+  endif()
+endif()
+
+if(NOT HAVE_LIBREALSENSE)
+  find_path(LIBREALSENSE_INCLUDE_DIR "librealsense2/rs.hpp"
+    PATHS "${LIBREALSENSE_INCLUDE}" ENV LIBREALSENSE_INCLUDE)
+  find_library(LIBREALSENSE_LIBRARIES "realsense2"
+    PATHS "${LIBREALSENSE_LIB}" ENV LIBREALSENSE_LIB)
+  if(LIBREALSENSE_INCLUDE_DIR AND LIBREALSENSE_LIBRARIES)
+    set(HAVE_LIBREALSENSE TRUE)
+    file(STRINGS "${LIBREALSENSE_INCLUDE_DIR}/librealsense2/rs.h" ver_strings REGEX "#define +RS2_API_(MAJOR|MINOR|PATCH|BUILD)_VERSION.*")
+    string(REGEX REPLACE ".*RS2_API_MAJOR_VERSION[^0-9]+([0-9]+).*" "\\1" ver_major "${ver_strings}")
+    string(REGEX REPLACE ".*RS2_API_MINOR_VERSION[^0-9]+([0-9]+).*" "\\1" ver_minor "${ver_strings}")
+    string(REGEX REPLACE ".*RS2_API_PATCH_VERSION[^0-9]+([0-9]+).*" "\\1" ver_patch "${ver_strings}")
+    set(LIBREALSENSE_VERSION "${ver_major}.${ver_minor}.${ver_patch}")  # informational
+    ocv_add_external_target(librealsense "${LIBREALSENSE_INCLUDE_DIR}" "${LIBREALSENSE_LIBRARIES}" "HAVE_LIBREALSENSE")
+  endif()
+endif()
+
+set(HAVE_LIBREALSENSE ${HAVE_LIBREALSENSE} PARENT_SCOPE)
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_ueye.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_ueye.cmake
@ -0,0 +1,23 @@
+if(NOT HAVE_UEYE)
+  if(WIN32)
+    if(X86_64)
+      set(_WIN_LIB_SUFFIX "_64")
+    endif()
+  endif()
+  find_path(UEYE_INCLUDE "ueye.h"
+    PATHS "${UEYE_ROOT}" ENV UEYE_ROOT "/usr" "C:/Program Files/IDS/uEye/Develop"
+    HINTS "${regpath}"
+    PATH_SUFFIXES "include")
+  find_library(UEYE_LIBRARY ueye_api${_WIN_LIB_SUFFIX}
+    PATHS "${UEYE_ROOT}" ENV UEYE_ROOT "/usr" "C:/Program Files/IDS/uEye/Develop"
+    HINTS "${regpath}"
+    PATH_SUFFIXES "lib")
+  if(UEYE_INCLUDE AND UEYE_LIBRARY)
+    set(HAVE_UEYE TRUE)
+  endif()
+endif()
+unset(_WIN_LIB_SUFFIX)
+
+if(HAVE_UEYE)
+  ocv_add_external_target(ueye "${UEYE_INCLUDE}" "${UEYE_LIBRARY}" "HAVE_UEYE")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_v4l.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_v4l.cmake
@ -0,0 +1,17 @@
+# --- V4L ---
+if(NOT HAVE_V4L)
+  set(CMAKE_REQUIRED_QUIET TRUE) # for check_include_file
+  check_include_file(linux/videodev2.h HAVE_CAMV4L2)
+  check_include_file(sys/videoio.h HAVE_VIDEOIO)
+  if(HAVE_CAMV4L2 OR HAVE_VIDEOIO)
+    set(HAVE_V4L TRUE)
+    set(defs)
+    if(HAVE_CAMV4L2)
+      list(APPEND defs "HAVE_CAMV4L2")
+    endif()
+    if(HAVE_VIDEOIO)
+      list(APPEND defs "HAVE_VIDEOIO")
+    endif()
+    ocv_add_external_target(v4l "" "" "${defs}")
+  endif()
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_ximea.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_ximea.cmake
@ -0,0 +1,30 @@
+if(NOT HAVE_XIMEA)
+  if(WIN32)
+    get_filename_component(regpath "[HKEY_CURRENT_USER\\Software\\XIMEA\\CamSupport\\API;Path]" ABSOLUTE)
+    if(NOT EXISTS ${regpath})
+      get_filename_component(regpath "[HKEY_LOCAL_MACHINE\\SOFTWARE\\XIMEA\\API_SoftwarePackage;Path]" ABSOLUTE)
+    endif()
+  endif()
+  if(X86_64)
+    set(lib_dir "API/x64" "API/64bit")
+    set(lib_suffix "64")
+  else()
+    set(lib_dir "API/x86" "API/32bit")
+    set(lib_suffix "32")
+  endif()
+  find_path(XIMEA_INCLUDE "xiApi.h"
+    PATHS "${XIMEA_ROOT}" ENV XIMEA_ROOT "/opt/XIMEA"
+    HINTS "${regpath}"
+    PATH_SUFFIXES "include" "API")
+  find_library(XIMEA_LIBRARY m3api xiapi${lib_suffix}
+    PATHS "${XIMEA_ROOT}" ENV XIMEA_ROOT "/opt/XIMEA"
+    HINTS "${regpath}"
+    PATH_SUFFIXES ${lib_dir})
+  if(XIMEA_INCLUDE AND XIMEA_LIBRARY)
+    set(HAVE_XIMEA TRUE)
+  endif()
+endif()
+
+if(HAVE_XIMEA)
+  ocv_add_external_target(ximea "${XIMEA_INCLUDE}" "${XIMEA_LIBRARY}" "HAVE_XIMEA")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_xine.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/detect_xine.cmake
@ -0,0 +1,7 @@
+if(NOT HAVE_XINE AND PKG_CONFIG_FOUND)
+  ocv_check_modules(XINE libxine QUIET)
+endif()
+
+if(HAVE_XINE)
+  ocv_add_external_target(xine "${XINE_INCLUDE_DIRS}" "${XINE_LIBRARIES}" "HAVE_XINE")
+endif()
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/init.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/init.cmake
@ -0,0 +1,33 @@
+if(NOT PROJECT_NAME STREQUAL "OpenCV")
+  include(FindPkgConfig)
+endif()
+
+macro(add_backend backend_id cond_var)
+  if(${cond_var})
+    include("${CMAKE_CURRENT_LIST_DIR}/detect_${backend_id}.cmake")
+  endif()
+endmacro()
+
+add_backend("ffmpeg" WITH_FFMPEG)
+add_backend("gstreamer" WITH_GSTREAMER)
+add_backend("v4l" WITH_V4L)
+
+add_backend("aravis" WITH_ARAVIS)
+add_backend("dc1394" WITH_1394)
+add_backend("gphoto" WITH_GPHOTO2)
+add_backend("msdk" WITH_MFX)
+add_backend("openni2" WITH_OPENNI2)
+add_backend("pvapi" WITH_PVAPI)
+add_backend("realsense" WITH_LIBREALSENSE)
+add_backend("ueye" WITH_UEYE)
+add_backend("ximea" WITH_XIMEA)
+add_backend("xine" WITH_XINE)
+
+add_backend("avfoundation" WITH_AVFOUNDATION)
+add_backend("ios" WITH_CAP_IOS)
+
+add_backend("dshow" WITH_DSHOW)
+add_backend("msmf" WITH_MSMF)
+
+add_backend("android_mediandk" WITH_ANDROID_MEDIANDK)
+add_backend("android_camera" WITH_ANDROID_NATIVE_CAMERA)
--- a/3rdparty/opencv-4.5.4/modules/videoio/cmake/plugin.cmake
+++ b/3rdparty/opencv-4.5.4/modules/videoio/cmake/plugin.cmake
@ -0,0 +1,56 @@
+function(ocv_create_builtin_videoio_plugin name target)
+
+  ocv_debug_message("ocv_create_builtin_videoio_plugin(${ARGV})")
+
+  if(NOT TARGET ${target})
+    message(FATAL_ERROR "${target} does not exist!")
+  endif()
+  if(NOT OpenCV_SOURCE_DIR)
+    message(FATAL_ERROR "OpenCV_SOURCE_DIR must be set to build the plugin!")
+  endif()
+
+  message(STATUS "Video I/O: add builtin plugin '${name}'")
+
+  foreach(src ${ARGN})
+    list(APPEND sources "${CMAKE_CURRENT_LIST_DIR}/src/${src}")
+  endforeach()
+
+  add_library(${name} MODULE ${sources})
+  target_include_directories(${name} PRIVATE "${CMAKE_CURRENT_BINARY_DIR}")
+  target_compile_definitions(${name} PRIVATE BUILD_PLUGIN)
+  target_link_libraries(${name} PRIVATE ${target})
+
+  foreach(mod opencv_videoio opencv_core opencv_imgproc opencv_imgcodecs)
+    ocv_target_link_libraries(${name} LINK_PRIVATE ${mod})
+    ocv_target_include_directories(${name} "${OPENCV_MODULE_${mod}_LOCATION}/include")
+  endforeach()
+
+  if(WIN32)
+    set(OPENCV_PLUGIN_VERSION "${OPENCV_DLLVERSION}" CACHE STRING "")
+    if(CMAKE_CXX_SIZEOF_DATA_PTR EQUAL 8)
+      set(OPENCV_PLUGIN_ARCH "_64" CACHE STRING "")
+    else()
+      set(OPENCV_PLUGIN_ARCH "" CACHE STRING "")
+    endif()
+  else()
+    set(OPENCV_PLUGIN_VERSION "" CACHE STRING "")
+    set(OPENCV_PLUGIN_ARCH "" CACHE STRING "")
+  endif()
+
+  set_target_properties(${name} PROPERTIES
+    CXX_STANDARD 11
+    CXX_VISIBILITY_PRESET hidden
+    DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}"
+    OUTPUT_NAME "${name}${OPENCV_PLUGIN_VERSION}${OPENCV_PLUGIN_ARCH}"
+  )
+
+  if(WIN32)
+    set_target_properties(${name} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${EXECUTABLE_OUTPUT_PATH})
+    install(TARGETS ${name} OPTIONAL LIBRARY DESTINATION ${OPENCV_BIN_INSTALL_PATH} COMPONENT plugins)
+  else()
+    install(TARGETS ${name} OPTIONAL LIBRARY DESTINATION ${OPENCV_LIB_INSTALL_PATH} COMPONENT plugins)
+  endif()
+
+  add_dependencies(opencv_videoio_plugins ${name})
+
+endfunction()